Dump it Here

//==================================
//     ConnorsTPS Long Only         ===
//     AFL By Willzy                 ===
//==================================

//     --- BackTest Settings --- //

// Set Trading Costs
SetOption("CommissionMode", 2); // Fixed $/Trade
SetOption("CommissionAmount",2); // $2 Commission
Spread = 0.0020; // Spread = 0.2% - may need adjustment based on instrument being traded               

// Account Finance Settings
SetOption("InterestRate",0);
SetOption("MarginRequirement",10); // Set For CFD type trading

// Trade Logic Settings
SetOption("AllowSameBarExit",False);
SetOption("ActivateStopsImmediately",False);
SetOption("AllowPositionShrinking",True);
SetOption("PriceBoundChecking",True);
SetOption("ReverseSignalForcesExit",False);
SetOption("UsePrevBarEquityForPosSizing",False);
SetOption("DisableRuinStop", True);

// --- Custom Functions --- //

// --- Backtest Method --- //
SetOption( "PortfolioReportMode", 0 );
SetOption("NoDefaultColumns",False);
SetOption("ExtraColumnsLocation", 1 );

// --- Monte Carlo Settings --- //
SetOption( "MCEnable", 2 );
SetOption( "MCRuns", 1000 );
SetOption( "MCStrawBroomLines", 10 );
SetOption( "MCNegativeDrawdown", 0 );
SetOption( "MCChartEquityScale", 0 );
SetOption( "MCUseEquityChanges", 0 );

// --- Position Sizing --- //
nPos = 1;
Leverage = 2;


SetOption( "InitialEquity", 10000 );
SetOption( "MaxOpenPositions", nPos );

// --- Variables and Parameters --- //
// Set maximum number of scale in trades - (original TPS logic - 1 2 3 4 )
maxScaleIn = 4;

// Indicator variables
maPeriod = 200;
rsiPeriod = 2;
rsiEntryLimit = 25;
rsiExitLimit = 70;

// --- Calcualte Indicators --- //
rsiIndicator = RSI(rsiPeriod);
SMA = MA(Close,maPeriod);

// --- Trading System Logic --- //
upTrend = 1;//C>MA(C,maPeriod);
buySignal = upTrend AND rsiIndicator < rsiEntryLimit AND Ref(rsiIndicator,-1) < rsiEntryLimit;
entryLong = buySignal;
entryPrice = Close * (1 + Spread);

sellSignal = rsiIndicator > rsiExitLimit;
exitLong = sellSignal;
exitPrice = Close;

// --- Combine Entries Exits and Stops --- //
Buy = Sell = Short = Cover = 0;
BuyPrice = entryPrice;
SellPrice = exitPrice;

// Initialize Arrays
PositionArray = Null;
LastEntryPriceArray = Null;
nBar = Null;

// Loop over all bars
for( i = 1; i < BarCount; i++ ){   
    if( EntryLong[i] ) // if entry signal on this bar
    {
        Position = PositionArray[i] = 1;
        lastEntryPrice = lastEntryPriceArray[i] = BuyPrice[i];
        
        for( j = i; j < BarCount; j++ ) // step forward one bar at a time to process the trade
        {
            // Remove Excess buySignals Until Exit is activated and i == j
            nBar[j] = j - i;
            if( nBar[j] > 0 )
            {
                buySignal[j] = 0;
                entryLong[j] = 0;
            
                // Check for ScaleIn First
                if( upTrend[j] == 1 && Close[j] < lastEntryPrice && Position < maxScaleIn )
                {
                    Position += 1;
                    PositionArray[j] = Position;
                    lastEntryPrice = BuyPrice[j];
                    lastEntryPriceArray[j] = lastEntryPrice;                   
                    continue;
                }
                
                lastEntryPriceArray[j] = lastEntryPriceArray[j-1];
                PositionArray[j] = PositionArray[j-1];           
                
                // If Exit Signal Sell on Current Bar
                if( ExitLong[j] )
                {
                    lastEntryPrice = lastEntryPriceArray[j] = Null;
                    Position = 0;
                    Sell[j] = 1;
                    i = j;
                    break;
                }               
            }
            
            // If No Exit Detected
            else
                if( j == BarCount - 1 )
                {
                    i = j;
                    break;
                }
        }
    }
}

takeAction = PositionArray > Ref(PositionArray,-1);
Buy = IIf((PositionArray == 1 AND takeAction), 1, IIf(takeAction, sigScaleIn, 0 ));

// Set Position Sizing here because it requries PositionArray input as variable
SetPositionSize( Leverage * PositionArray * 10, spsPercentOfEquity );

// --- Create Figures and Plots --- //

// Plot Price
PlotOHLC( O, H, L, C, "Price", colorBlack, styleBar );

// Plot Indicators
Plot(MA(Close,maPeriod),"SMA",colorBlue,styleLine);

//Plot Entry Exit and Setup Signals
PlotShapes( IIf( Buy == 1, shapeHollowCircle, IIf(Buy > 1 , shapeHollowCircle, shapeNone )), colorGreen, 0, BuyPrice, 0 );
PlotShapes( IIf( Sell == 1, shapeHollowCircle, shapeNone ), colorRed, 0 , SellPrice, 0 );

FirstVisibleBar = Status( "FirstVisibleBar" );
Lastvisiblebar = Status( "LastVisibleBar" );

for( b = Firstvisiblebar; b <= Lastvisiblebar AND b < BarCount; b++ ){
    if( Buy[b] ){
        PlotText( NumToStr( PositionArray[b], 2 ), b, Low[b]*0.99, colorBlack );
    }

    //if( Sell[b] ){
    //    PlotText( "Exit", b, SellPrice[b], colorBlue );
    //}
}

// --- END --- //

// --- Create Explore Filter for Error Checking --- //
Filter = 1;
AddColumn( Close, "Close", 1.2, IIf( C<Ref(C,-1), colorRed, colorGreen ) );
AddColumn( buySignal, "BuySig", 1 );
AddColumn( entryLong, "EntryLong", 1 );
AddColumn( PositionSize, "PosSize", 1 );
AddColumn( nBar, "nBar", 1 );
AddColumn( positionArray, "PositionArray", 1 );
AddColumn( lastEntryPriceArray, "lastEntryPriceArray", 1.2 );
AddColumn( sellSignal, "SellSig", 1 );
AddColumn( exitLong, "ExitLong", 1 );