# Chandelier Exit/Stop



## hooikk (24 July 2008)

I've never quite understood how to use the Chandelier Exit/stop as per plotted by most charting software. Theres often instances when the stop is above the close of the latest bar e.g. The stop is calculated at $41, while the closing price was $38. 

If I wanted to enter a trade the next day, what should the stop-loss level be? It obviously can't be $41 if I'm entering the trade in the vicinity of $38.

The definition as provided by the traderclub forum :

_The Chandelier Exit hangs a trailing stop from either the highest high of the trade or the highest close of the trade. The distance from the high point to the trailing stop is probably best measured in units of Average True Range. However the distance from the high point could also be measured in dollars or in contract based points. _

From the definition, does this mean the Chandelier exit can only be calculated only AFTER a trade is entered?


----------



## wayneL (24 July 2008)

hooikk said:


> I've never quite understood how to use the Chandelier Exit/stop as per plotted by most charting software. Theres often instances when the stop is above the close of the latest bar e.g. The stop is calculated at $41, while the closing price was $38.
> 
> If I wanted to enter a trade the next day, what should the stop-loss level be? It obviously can't be $41 if I'm entering the trade in the vicinity of $38.
> 
> ...



That's not right.

What software are you using and what chandelier exit code are you using.

Someone might be able to help if we know that.


----------



## howardbandy (24 July 2008)

Hi Hooikk --

You are correct -- the chandelier stop, or any trailing stop, has its initial exit point set after the trade has been entered.  

For a long position, the chandelier stop will always be lower than the high or the close, whichever is being used to "hang" the chandelier.  And it will only move up, never down.

There is another algorithm that is often used as a trailing stop -- the stop portion of the parabolic stop and reverse, SAR.  It, also, has its initial exit point set only after the trade has been entered, and only moves in the direction of the trade.  The SAR is sometimes run as a complete trading system, with the exit from a long trade being an entry to a short trade, and the exit from the short trade being an entry to a long trade.

Both of these trailing exit techniques -- chandelier and parabolic -- work well as components of trend following systems.  Use whatever entry works for you, use whatever exit works for you, and include one of these trailing stops as an alternative exit.

Thanks,
Howard


----------



## hooikk (26 July 2008)

wayneL said:


> That's not right.
> 
> What software are you using and what chandelier exit code are you using.
> 
> Someone might be able to help if we know that.




At the moment, I've coded up the Chandelier Exit in Amibroker using the formula from "Come Into My Trading Room" by Dr.Elder. Fairly simple implementation:


```
PrdLookback = Param("Lookback Period", 21, 1, 100, 1, 1);
Coef = Param("Coefficient", 3, 1, 5, 0.1, 0.1);

ChandelierLong =HHV(High, PrdLookback) - (Coef * ATR(PrdLookback));
ChandelierShort = LLV(Low, PrdLookback) + (Coef * ATR(PrdLookback));


Plot(ChandelierLong , "Long Chandelier ", ParamColor("Long Chandelier Color", colorRed), ParamStyle("Long Chandelier Style", styleDashed));
Plot(ChandelierShort , "Short Chandelier Exit", ParamColor("Short Chandelier Color", colorBlue), ParamStyle("Short Chandelier Style", styleDashed));
```

The plot doesn't really make sense, especially for stocks with a large rally and/or slide. I end up with stop-loss line that plots above the prices for stocks every now and then.

If I wanted to use this stop to make enter a trade tomorrow, should the process be:
1) Calculate the 'distance': 3 x ATR(10)
2) If today's high is $37 and the ATR(10) = 1.5, my stop should be $32.50
3 -1) If the stock closes at $38 the next day, my stop will be raised to $33.50
3-2) If the stock closes at $38 the next day and the ATR(10) becomes 1.4, my new stop should be raised to $33.80  i.e $38 - 3*1.4


----------



## captain black (26 July 2008)

There's a few Chandelier Exit formulas in the AFL library as well as a single-line version in the "Applystop" example in the Amibroker help files.


----------



## wayneL (26 July 2008)

Try this one (hat tip to Stevo):


```
// ATR Trailing stop 

multiplier = Param("ATR Multiplier", 3, 0, 10, 0.1);
myATR= multiplier*ATR(10); // calculate ATR
initial=H-myATR; // raw stop - not racheted

stop[ 0 ] = Close[ 0 ];
for( i = 1 ; i < BarCount; i++)
{
 if( Close[ i ] > stop[ i - 1])
{
 temp = Close[ i ] - myATR[ i ];
 if( temp > stop[ i - 1 ] ) stop[ i ] = temp;
 else stop[ i ] = stop[ i - 1 ];
}
 else
 stop[ i ] = initial[ i ];
}

Plot( Max(stop,Ref(stop,-1)), "ATR Stop", colorCustom13, styleDashed);
```

The short version:


```
// ATR Trailing stop - Short
 
multiplier = Param("ATR Multiplier", 3, 0, 10, 0.1);
myATR= multiplier*ATR(10); // calculate ATR
initial=L+myATR; // raw stop - not racheted

stop[ 0 ] = Close[ 0 ];
for( i = 1 ; i < BarCount; i++)
{
 if( Close[ i ] < stop[ i - 1])
{
 temp = Close[ i ] + myATR[ i ];
 if( temp < stop[ i - 1 ] ) stop[ i ] = temp;
 else stop[ i ] = stop[ i - 1 ];
}
 else
 stop[ i ] = initial[ i ];
}

Plot( Min(stop,Ref(stop,-1)), "ATR Stop", colorWhite, styleDashed);
```


----------



## CamKawa (27 July 2008)

For more reading on the topic and a free Metastock plug-in.
http://www.tradernexus.com/advancedstop/advancedstop.html


----------

