/*Variables*/
/***********/
T= SetOption("InitialEquity", 7500); /*Your starting capital*/
U= Param("What % of your capital are you willing to risk?", 1, 0, 100); /*The % of capital that is going to be risked per trade*/
W= Param("Number of bars to compare lowest close (for Covering)", 5, 0, 100); /*The number of previous bars today's close will be compared to*/
X= Param("Number of bars to compare highest close (for Selling)", 5, 0, 100); /*The number of previous bars today's close will be compared to*/
Y= MA(Volume,10); /*Formula for Average Volume*/
Z= Param("Number of bars to compare size of spread", 15, 0, 100); /*The number of previous bars today's spread will be compared to*/
risk= (U/100)*T; /*The $ value that is going to be risked per trade*/
spread= H-L; /*Size of the spread*/
mid= L + spread/2; /*The midpoint of a bar*/
/*Going Long*/
/************/
/*Buy Condition: Three consecutive up-thrust days with successively increasing volume*/
Buy = Ref(C,-2)<Ref(C,-1) AND Ref(C,-1)<C AND Ref(C,-2)<C AND Ref(V,-2)<Ref(V,-1) AND Ref(V,-1)<V AND Ref(V,-2)<V;
/*Sell Condition #1: Three days where the close is sideways (+/- 5% of each other) and volume is successively decling but larger than average for the first two days*/
/*Sell = (Ref(C,-2)<1.025*Ref(C,-1) AND Ref(C,-2)>0.975*Ref(C,-1)) AND (Ref(C,-2)<1.025*C AND Ref(C,-2)>0.975*C) AND (Ref(C,-1)<1.025*C AND Ref(C,-1)>0.975*C);*/
/*Sell Condition #2: Sell on the bar with the smallest spread for the past 15 days, above average volume and a close towards the high with the bar in an uptrend.*/
Sell = spread<=LLV(spread,Z) AND V>Y AND C>mid AND C>=HHV(C,X);
/*Going Short*/
/*************/
/*Short Condition: Three consecutive down-thrust days with successively increasing volume*/
Short = Ref(C,-2)>Ref(C,-1) AND Ref(C,-1)>C AND Ref(C,-2)>C AND Ref(V,-2)<Ref(V,-1) AND Ref(V,-1)<V AND Ref(V,-2)<V;
/*Cover Condition: Cover on bar with lowest close for X period, above average volume, small spread and with a close towards the low*/
Cover = spread<=LLV(spread, Z) AND V>Y AND C<mid AND C<=LLV(C,X);
/*Timing the Trades*/
/*******************/
SetTradeDelays(1,1,1,1);
BuyPrice = Open;
SellPrice = Open;
ShortPrice = Open;
CoverPrice = Open;
/*Stop Losses & Position Size*/
/*****************************/
ApplyStop(0,2,Ref(C,-1),1); /*Apply a static stop loss at yesterday's close. If triggered, exit intraday*/
ApplyStop(2,2,Ref(mid,-1),1); /*Apply a trailing stop at the middle of the previous bar. If triggered, exit intraday*/
PositionSize = risk/(C-Ref(C,-1))*BuyPrice; /*The position size*/
SetOption("MaxOpenPositions", Optimize("MaxOpenPositions", 3, 1, 10, 1)); /*The maximum number of trades open at any one time. Optimizing.*/