Greetings all --
You can runs tests to find out what works for the issues you plan to trade. Here is a short AmiBroker code segment that tests all values for the two moving averages, and buys when the first moving average crosses up through the second moving average. (It also computes the equity and plots the price, the moving average, and the equity. You only need the first six lines of code to test the system -- the rest is to give a visual plot of the results.)
Note that there is no restriction in the code to keep the first moving average shorter than the second.
If the "best" set of lengths has the first moving average length shorter than the second, then the results are telling you that you should be buying strength -- buy as the shorter moving average crosses up through the longer one -- the way most of the literature suggests. This is results in a "trend following" system.
If the "best" set of lengths has the first longer then the second, then the results are telling you that you should be selling strength -- buy as the shorter moving average falls down through the longer one. (Buy as the longer moving average rises up through the shorter one.) Opposite to common thought. This results in a "mean reversion" system.
So --- try it out for yourself.
In most cases -- for most tickers, most time frames, and most measures of goodness (the objective function) -- the "best" set of lengths will suggest that a mean reversion system works better than a trend following system.
One implication is that the common wisdom of buying when the price closes above its, say, 50 day moving average, has it backwards -- that is the time to sell.
//----------------------------
//
// MACrossSystem.afl
//
// The classic Moving Average crossover
// using simple Moving Averages
//
// Set up the lengths for the moving averages
Length1 = Param("Length1",6,1,81,2);
Length2 = Param("Length2",35,2,200,2);
// The Moving Average calculations
MA1 = MA(C,Length1);
MA2 = MA(C,Length2);
// The Buy and Sell logic
// Buy when MA1 crosses from below MA2 to above MA2.
Buy = Cross(MA1,MA2);
Sell = Cross(MA2,MA1);
// Compute the equity for the single ticker
e = Equity();
Maxe = LastValue(Highest(e));
Plot( Close, "Price", colorBlack, styleCandle );
// Plot the MA lines.
Plot(MA1,"MA1",colorGreen,styleLine);
Plot(MA2,"MA2",colorBlue,styleLine);
// Plot the Buy and Sell arrows.
shape = Buy * shapeUpArrow + Sell * shapeDownArrow;
PlotShapes(shape, IIf(Buy,colorGreen,colorRed), 0, IIf(Buy,Low,High));
// Plot the equity curve
Plot(e,"Equity",colorBlue,styleLine|styleOwnScale,0,Maxe);
Plot(10000,"",colorBlue,styleLine|styleOwnScale,0,Maxe);
GraphXSpace = 5;
//Figure 9.1 MA Cross System
//
//----------------------------------------------
Thanks for listening,
Howard